برنامج البحث المشترك في قانون التامينات واللائحة التنفيذية وقانون العمل

 

برنامج البحث المشترك في قانون التامينات واللائحة التنفيذية وقانون العمل

المعادلات المستخدمه تتطلب اكسل حديث او اكسل 365 

=LET(

    xl, VSTACK(

        LET(

            ar, 'law148 -2019'!B1:B1029,

            arr, 'law148 -2019'!$C$1:$C$1029,

            x, UNIQUE(

                XLOOKUP(

                    FILTER(

                        arr,

                        ISNUMBER(SEARCH(البحث!B4, arr)),

                        0

                    ),

                    arr,

                    ar,

                    0

                )

            ),

            xx, MAP(

                x,

                LAMBDA(a,

                    TEXTJOIN(

                        CHAR(10),

                        TRUE,

                        FILTER(arr, ar = a, 0)

                    )

                )

            ),

            HSTACK(

                " قانون التامينات رقم 148 لسنة 2019" &

                    " " & LEFT(xx, SEARCH(")", xx, 1)),

                xx

            )

        ),

        LET(

            ar, 'la-law149-2019'!$B$1:$B$2050,

            arr, 'la-law149-2019'!$C$1:$C$2050,

            x, UNIQUE(

                XLOOKUP(

                    FILTER(

                        arr,

                        ISNUMBER(SEARCH(البحث!B4, arr)),

                        0

                    ),

                    arr,

                    ar,

                    0

                )

            ),

            xx, MAP(

                x,

                LAMBDA(a,

                    TEXTJOIN(

                        CHAR(10),

                        TRUE,

                        FILTER(arr, ar = a, 0)

                    )

                )

            ),

            HSTACK(

                " اللائحة التنفيذية قانون التامينات رقم 148 لسنة 2019" &

                    " " & LEFT(xx, SEARCH(")", xx, 1)),

                xx

            )

        ),

        LET(

            ar, 'law 12-2003'!$B$1:$B$1007,

            arr, 'law 12-2003'!$C$1:$C$1007,

            x, UNIQUE(

                XLOOKUP(

                    FILTER(

                        arr,

                        ISNUMBER(SEARCH(البحث!B4, arr)),

                        0

                    ),

                    arr,

                    ar,

                    0

                )

            ),

            xx, MAP(

                x,

                LAMBDA(a,

                    TEXTJOIN(

                        CHAR(10),

                        TRUE,

                        FILTER(arr, ar = a, 0)

                    )

                )

            ),

            HSTACK(

                " قانون العمل رقم 12 لسنة 2003" & " " &

                    LEFT(xx, SEARCH(")", xx, 1)),

                xx

            )

        )

    ),

    xxl, FILTER(

        xl,

        CHOOSECOLS(xl, 2) <> "0",

        "من فضــــــــــــــــــلك ادخل  كلمــــــــــــــة الـــــــــــــــبحث"

    ),

    IF(

        OR(B4 = "", B4 = " "),

        "من فضــــــــــــــــــلك ادخل  كلمــــــــــــــة الـــــــــــــــبحث",

        xxl

    )

)

 رابط التحميل 

https://docs.google.com/spreadsheets/d/1Na51VpX0XZUA7dJAGjsDpFJiuNJ6St3y/edit?usp=drive_link&ouid=115648638686957252471&rtpof=true&sd=true

ملحوظة الملف يعمل مع اصدارات الاوفيس الحديثة و اوفيس 365